NNTPGrab

AC_INIT(nntpgrab, 0.6.92)

AC_DEFINE(MAJOR_VERSION, 0, [Major version number])

AC_DEFINE(MINOR_VERSION, 6, [Minor version number])

AC_DEFINE(MICRO_VERSION, 92, [Micro version number])

AM_INIT_AUTOMAKE([no-dist-gzip dist-bzip2])

AC_PROG_CXX

AC_PROG_INSTALL

AC_LIBTOOL_DLOPEN

AC_LIBTOOL_WIN32_DLL

AC_DISABLE_STATIC

AC_CONFIG_HEADERS(config.h)

AC_SUBST(CPPFLAGS,$CPPFLAGS)

AC_PROG_LIBTOOL

AC_CHECK_SIZEOF(time_t)

AC_CHECK_SIZEOF(long)

AM_PROG_CC_C_O

GETTEXT_PACKAGE=NNTPGrab

AC_SUBST(GETTEXT_PACKAGE)

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])

dnl Find pkg-config

AC_PATH_PROG(PKG_CONFIG, pkg-config, no)

if test "x$PKG_CONFIG" = "xno"; then

 AC_MSG_ERROR([You need to install pkg-config])

fi

AM_PATH_GLIB_2_0("2.10.0")

# Optional configure arguments

AC_ARG_ENABLE(dbus,

 [  --disable-dbus          Activate DBUS integration (enabled by default)],

 [case "x${enableval}" in

         xyes) dbus=true ;;

         xno) dbus=false ;;

         *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;

 esac],[dbus=true])

AC_ARG_ENABLE(online-search,

 [  --disable-online-search Activate support for the Online Search(enabled by default)],

 [case "x${enableval}" in

         xyes) online_search=true ;;

         xno) online_search=false ;;

         *) AC_MSG_ERROR(bad value ${enableval} for --disable-online-search) ;;

 esac],[online_search=true])

AC_ARG_ENABLE(proxy,

 [  --disable-proxy         Activate support for downloading using a proxy server (enabled by default)],

 [case "x${enableval}" in

         xyes) proxy=true ;;

         xno) proxy=false ;;

         *) AC_MSG_ERROR(bad value ${enableval} for --disable-proxy) ;;

 esac],[proxy=true])

AC_ARG_ENABLE(testsuite,

 [  --disable-testsuite     Build the testsuite (enabled by default)],

 [case "x${enableval}" in

         xyes) testsuite=true ;;

         xno) testsuite=false ;;

         *) AC_MSG_ERROR(bad value ${enableval} for --disable-testsuite) ;;

 esac],[testsuite=true])

AC_ARG_ENABLE(online-tests,

 [  --disable-online-tests  Disable the tests from the testsuite which require an internet connection (enabled by default)],

        [case "x${enableval}" in

                xyes) online_tests=true ;;

                xno) online_tests=false ;;

                *) AC_MSG_ERROR(bad value ${enableval} for --disable-online-tests) ;;

        esac],[online_tests=true])

# Search for GLib

PKG_CHECK_MODULES(GLIB,

 glib-2.0 >= 2.10.0 gthread-2.0 gmodule-2.0 gobject-2.0,

 ,

 [AC_MSG_ERROR([* GLib 2.10.0 or higher could not be found (is the package glib2-devel installed?)])])

# Search for GIO

PKG_CHECK_MODULES(GIO,

 glib-2.0 >= 2.16.0 gio-2.0,

 have_gio=true; AC_DEFINE_UNQUOTED(HAVE_GIO, 1, [Do we have GIO]),

 have_gio=false; [AC_MSG_RESULT([* GLib 2.16.0 or higher could not be found. Without GLib 2.16.0, automatic NZB import won't be possible])])

# Search for socket support in GIO

AC_MSG_CHECKING(if GIO >= 2.26.0)

pkg-config --atleast-version=2.26.0 gio-2.0

if test `echo $?` = 0; then

 AC_MSG_RESULT([yes]);

 AC_DEFINE_UNQUOTED(HAVE_GIO_SOCKET, 1, [Do we have socket support in GIO])

else

 AC_MSG_RESULT([no])

fi

# Search for GTest support in GLib

AC_MSG_CHECKING(if we need to enable the testsuite)

pkg-config --atleast-version=2.16.0 glib-2.0

if test `echo $?` != 0; then

 if test "$testsuite" = "true" ; then

         testsuite=false

 fi

fi

if test "$testsuite" = "true" ; then

      AC_MSG_RESULT([yes])

else

      AC_MSG_RESULT([no])

fi

AM_CONDITIONAL(BUILD_TESTSUITE, $testsuite)

AM_CONDITIONAL(ENABLE_ONLINE_TESTS, $online_tests)

# Search for dbus-glib

if test "$dbus" = "true" ; then

      PKG_CHECK_MODULES(DBUS,

              dbus-glib-1 >= 0.60,

              have_dbus=true; AC_DEFINE_UNQUOTED(HAVE_DBUS, 1, [Do we have DBus-glib]),

              have_dbus=false; [AC_MSG_RESULT([* DBUS-Glib 0.60 or higher could not be found (is the package dbus-devel and/or dbus-glib-devel installed?).])])

fi

# Search for libsoup

if test "$online_search" = "true" ; then

      PKG_CHECK_MODULES(SOUP,

              libsoup-2.4,

              have_soup=true; [AC_DEFINE_UNQUOTED(HAVE_SOUP, 1, [Do we have libsoup])],

              have_soup=false; [AC_MSG_RESULT([* libsoup 2.4 or higher could not be found (is the package libsoup-devel installed?). Without libsoup, the NZBCreator service can't be accessed])])

      PKG_CHECK_MODULES(SOUP_GZIP,

              libsoup-2.4 >= 2.28.2,

              [AC_DEFINE_UNQUOTED(HAVE_SOUP_GZIP, 1, [Do we have gzip support in libsoup])],

              [AC_MSG_RESULT([* libsoup 2.28.2 or higher could not be found. This is required to enable compression in the NZBCreator service])])

else

    have_soup="false"

fi

# Search for libproxy and libsoup-gnome

if test "$proxy" = "true" ; then

      PKG_CHECK_MODULES(SOUP_GNOME,

              libsoup-gnome-2.4,

              [AC_DEFINE_UNQUOTED(HAVE_SOUP_GNOME, 1, [Do we have libsoup-gnome])],

              [AC_MSG_RESULT([* libsoup-gnome 2.4 or higher could not be found (is the package libsoup-devel installed?). Without libsoup-gnome proxy settings won't be detected on Linux])])

      PKG_CHECK_MODULES(LIBPROXY,

              libproxy-1.0,

              [AC_DEFINE_UNQUOTED(HAVE_LIBPROXY, 1, [Do we have libproxy])],

              [AC_MSG_RESULT([* libproxy could not be found (is the package libproxy-devel installed?). Without libproxy proxy settings won't be detected])])

fi

# Search for glib-networking

AC_MSG_CHECKING([for glib-networking (glib TLS implementation)])

save_CFLAGS="$CFLAGS"

save_LIBS="$LIBS"

CFLAGS="$CFLAGS $GIO_CFLAGS"

LIBS="$LIBS $GIO_LIBS"

AC_RUN_IFELSE([AC_LANG_PROGRAM([#include ],

                              [g_type_init (); return !g_tls_backend_supports_tls (g_tls_backend_get_default ());])],

      [have_glib_networking=yes]; [AC_DEFINE_UNQUOTED(HAVE_GLIB_NETWORKING, 1, [Do we have glib-networking])],

      [have_glib_networking=no],

      [have_glib_networking="unknown (cross-compiling)"])

CFLAGS="$save_CFLAGS"

LIBS="$save_LIBS"

AC_MSG_RESULT($have_glib_networking)

AC_SUBST(GLIB_LIBS)

AC_SUBST(GLIB_CFLAGS)

AC_SUBST(GIO_LIBS)

AC_SUBST(GIO_CFLAGS)

AM_CONDITIONAL(HAVE_GIO, $have_gio)

AC_SUBST(LIBXML2_LIBS)

AC_SUBST(LIBXML2_CFLAGS)

AC_SUBST(DBUS_LIBS)

AC_SUBST(DBUS_CFLAGS)

AM_CONDITIONAL(HAVE_DBUS, $have_dbus)

AC_SUBST(SOUP_LIBS)

AC_SUBST(SOUP_CFLAGS)

AC_SUBST(SOUP_GNOME_LIBS)

AC_SUBST(SOUP_GNOME_CFLAGS)

AC_SUBST(LIBPROXY_LIBS)

AC_SUBST(LIBPROXY_CFLAGS)

AC_ARG_ENABLE(ssl,

      [  --disable-ssl           Activate NNTP-over-SSL support (enabled by default)],

      [case "x${enableval}" in

              xyes) ssl=true ;;

              xno) ssl=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-ssl) ;;

      esac],[ssl=true])

AC_ARG_ENABLE(php_module,

      [  --enable-php-module     Compile an PHP module which allows PHP scripts to call NNTPGrab methods (disabled by default)],

      [case "x${enableval}" in

              xyes) php_module=true ;;

              xno) php_module=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --enable-php-module) ;;

      esac],[php_module=false])

AM_CONDITIONAL(ENABLE_PHP_MODULE, $php_module)

AC_ARG_ENABLE(networkmanager,

      [  --disable-networkmanager

                          Activate NetworkManager integration (enabled by default)],

      [case "x${enableval}" in

              xyes) networkmanager=true ;;

              xno) networkmanager=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-networkmanager) ;;

      esac],[networkmanager=true])

if test "$networkmanager" = "true" ; then

      PKG_CHECK_MODULES(NETWORKMANAGER, libnm-glib, have_networkmanager=true,have_networkmanager=false)

      if test "$have_networkmanager" = "false" ; then

              PKG_CHECK_MODULES(NETWORKMANAGER,

                      libnm_glib > 0.7.0,

                      have_networkmanager=true,

                      [AC_MSG_RESULT([* NetworkManager-glib could not be found (is the package NetworkManager-glib-devel installed?) Without NetworkManager-glib, NetworkManager integration won't be possible])]; have_networkmanager=false)

      fi

else

    have_networkmanager=false

fi

AC_ARG_ENABLE(automatic_shutdown,

      [  --disable-automatic-shutdown

                          Activate support for automatic shutdown (enabled by default)],

      [case "x${enableval}" in

              xyes) automatic_shutdown=true ;;

              xno) automatic_shutdown=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-automatic-shutdown) ;;

      esac],[automatic_shutdown=true])

AC_SUBST(NETWORKMANAGER_LIBS)

AC_SUBST(NETWORKMANAGER_CFLAGS)

AM_CONDITIONAL(HAVE_NETWORKMANAGER, $have_networkmanager)

AC_ARG_ENABLE(gui,

      [  --disable-gui           Turn on GUI client (enabled by default)],

      [case "x${enableval}" in

              xyes) gui=true ;;

              xno)  gui=false ;;

              x) gui=true ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-gui) ;;

      esac],[gui=true])

AC_ARG_ENABLE(gtk3,

      [  --disable-gtk3          Build against GTK+ 3 if it's available (enabled by default)],

      [case "x${enableval}" in

              xyes) gtk3=true ;;

              xno) gtk3=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-gtk3) ;;

      esac],[gtk3=true])

AC_ARG_ENABLE(notifications,

      [  --disable-notifications Activate support for showing notifications using libnotify (enabled by default)],

      [case "x${enableval}" in

              xyes) notifications=true ;;

              xno) notifications=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-notifications) ;;

      esac],[notifications=true])

AM_CONDITIONAL(ENABLE_GUI, $gui)

if [ "$gui" = "true" ]; then

      if test "$gtk3" = "true" ; then

              PKG_CHECK_MODULES(GTK3,

                      gtk+-3.0 gdk-3.0 gthread-2.0,

                      have_gtk3=true; AC_DEFINE_UNQUOTED(HAVE_GTK3, 1, [Do we have GTK-3 available]),

                      have_gtk3=false; [AC_MSG_RESULT([* GTK+-3.0 or higher could not be found (is the package gtk3+-devel installed?)])])

      else

              have_gtk3="false"

      fi

      if test "$have_gtk3" = "false" ; then

              PKG_CHECK_MODULES(GTK,

                      gtk+-2.0 gdk-2.0 gthread-2.0,

                      ,

                      [AC_MSG_ERROR([* GTK+-2.2 or higher could not be found (is the package gtk2+-devel installed?)])])

              AC_MSG_CHECKING(if GTK >= 2.12.0)

              pkg-config --atleast-version=2.12.0 gtk+-2.0

              if test `echo $?` = 0; then

                      AC_MSG_RESULT([yes])

              else

                      AC_MSG_RESULT([no])

                      PKG_CHECK_MODULES(GLADE,

                              libglade-2.0,

                              ,

                              [AC_MSG_ERROR([* Glade 2.0 or higher could not be found (is the package libglade2-devel installed?)])])

              fi

      fi

      if test "$notifications" = "true" ; then

              PKG_CHECK_MODULES(LIBNOTIFY,

                      libnotify >= 0.4.1,

                      AC_DEFINE_UNQUOTED(HAVE_LIBNOTIFY, 1, [Do we have libnotify available]),

                      [AC_MSG_RESULT([* libnotify 0.4.1 or higher could not be found (is the package libnotify-devel installed?). Without libnotify, notification balloons aren't possible])])

              AC_MSG_CHECKING(if libnotify >= 0.7.0)

              pkg-config --atleast-version=0.7.0 libnotify

              if test `echo $?` = 0; then

                      AC_MSG_RESULT([yes])

                      AC_DEFINE_UNQUOTED(HAVE_LIBNOTIFY_0_7, 1, [Do we have libnotify 0.7 available])

              else

                      AC_MSG_RESULT([no])

              fi

      fi

      if test "$automatic_shutdown" = "true" ; then

              PKG_CHECK_MODULES(POLKIT,

                      polkit-gobject-1,

                      AC_DEFINE_UNQUOTED(HAVE_POLKIT1, 1, [Do we have PolicyKit 1.0 available]),

                      [PKG_CHECK_MODULES(POLKIT,

                              polkit-gnome,

                              AC_DEFINE_UNQUOTED(HAVE_POLKIT_OLD, 1, [Do we have PolicyKit 0.9 available]),

                              [AC_MSG_RESULT([* PolicyKit could not be found (is the package polkit-devel or PolicyKit-gnome-devel installed?). Without PolicyKit, automatic shutdown won't be possible])])

                      ])

      fi

      PKG_CHECK_MODULES(LIBXML2,

              libxml-2.0,

              ,

              [AC_MSG_ERROR([* LibXML 2.0 or higher could not be found (is the package libxml2-devel installed?)])])

fi

AC_ARG_ENABLE(par2cmdline-check,

      [  --disable-par2cmdline-check

                          Check for the existance of the par2 binary (enabled by default)],

      [case "x${enableval}" in

              xyes) par2_check=true ;;

              xno) par2_check=false ;;

              *) AC_MSG_ERROR(bad value ${enableval} for --disable-par2cmdline-check) ;;

      esac],[par2_check=true])

if test "$par2_check" = "true" ; then

      AC_CHECK_PROGS([PAR2CMDLINE], [par2])

      if test "x$PAR2CMDLINE" = "x" ; then

              AC_MSG_ERROR([par2cmdline is not found. This is required for NNTPGrab])

      fi

fi

AC_SUBST(GTK3_LIBS)

AC_SUBST(GTK3_CFLAGS)

AC_SUBST(GTK_LIBS)

AC_SUBST(GTK_CFLAGS)

AC_SUBST(GLADE_CFLAGS)

AC_SUBST(GLADE_LIBS)

AC_SUBST(POLKIT_LIBS)

AC_SUBST(POLKIT_CFLAGS)

AC_SUBST(LIBNOTIFY_LIBS)

AC_SUBST(LIBNOTIFY_CFLAGS)

# check for gtk-doc

GTK_DOC_CHECK([1.14],[--flavour no-tmpl])

dnl Default search paths for headers and libs

dnl ----------------------------------------

ac_default_lib_searchpath="/sw/lib /usr/lib64 /usr/local/lib64 /usr/lib /usr/local/lib /opt/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /usr/lib/openssl/lib /usr/X11R6/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /usr/X11R6/lib/mozilla* /usr/lib/mozilla*"

ac_default_lib_searchpath="$ac_default_lib_searchpath /usr/local/mozilla* /usr/local/mozilla*/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /usr/local/ssl*/lib /usr/local/lib/openssl"

ac_default_lib_searchpath="$ac_default_lib_searchpath /opt/gnome/lib/mozilla /opt/mozilla/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /usr/lib/curl /usr/local/lib/curl /opt/curl/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /opt/MozillaThunderbird/lib64 /opt/openssl/lib"

ac_default_lib_searchpath="$ac_default_lib_searchpath /sw/lib/mozilla /dist/lib"

ac_default_inc_searchpath="/sw/include /usr/include /usr/include/libxml2 /usr/local/include "

ac_default_inc_searchpath="$ac_default_inc_searchpath /opt/include /opt/openssl/include "

ac_default_inc_searchpath="$ac_default_inc_searchpath /usr/lib/openssl/include /usr/include/mozilla*"

ac_default_inc_searchpath="$ac_default_inc_searchpath /usr/local/mozilla* /usr/local/mozilla*/include"

ac_default_inc_searchpath="$ac_default_inc_searchpath /usr/local/ssl/include /usr/local/include/openssl"

ac_default_inc_searchpath="$ac_default_inc_searchpath /usr/include/mozilla*/gtkembedmoz /usr/local/include/mozilla*/gtkembedmoz"

ac_default_inc_searchpath="$ac_default_inc_searchpath /opt/gnome/include/mozilla /opt/mozilla/include"

ac_default_inc_searchpath="$ac_default_inc_searchpath /usr/include/curl /usr/local/include/curl /opt/curl/include"

ac_default_inc_searchpath="$ac_default_inc_searchpath /sw/include/mozilla /usr/include/pcre /dist/include"

dnl --------------------

dnl OS specific settings

dnl --------------------

case "$host_os" in

        mingw32)

                CPPFLAGS="$CPPFLAGS -mms-bitfields"

                CFLAGS="$CFLAGS -DOS=\"\\\"Windows\\\"\""

                AC_CHECK_TOOL(WINDRES, windres, no)

                if test "$WINDRES" = no; then 

                        AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.]) 

                fi

                AM_CONDITIONAL(WIN32, true)

                AC_DEFINE(WIN32, 1, [Is this a Win32 platform])

                AM_CONDITIONAL(DARWIN, false);;

       cygwin)

                CFLAGS="$CFLAGS -DOS=\"\\\"Windows\\\"\""

                AC_CHECK_TOOL(WINDRES, windres, no)

                if test "$WINDRES" = no; then

                        AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])

                fi

                AM_CONDITIONAL(WIN32, true)

                AC_DEFINE(WIN32, 1, [Is this a Win32 platform])

                AM_CONDITIONAL(DARWIN, false)

                LDFLAGS="$LDFLAGS -mwindows";;

        darwin*)

                CFLAGS="$CFLAGS -DOS=\"\\\"Mac_OS_X/X86\\\"\""

                CPPFLAGS="$CPPFLAGS -DDARWIN"

                AM_CONDITIONAL(WIN32, false)

                AM_CONDITIONAL(DARWIN, true);;

        *)

                CFLAGS="$CFLAGS -DOS=\"\\\"`uname -s`\\\"\""

                AM_CONDITIONAL(WIN32, false)

                AM_CONDITIONAL(DARWIN, false);;

esac

dnl ---------------------

dnl Mac OS X integration

dnl ---------------------

if test "$host_os" = "darwin9" -o "$host_os" = "darwin10" -o "$host_os" = "darwin10.2.0" ; then

  if [ "$gui" = "true" ]; then

    PKG_CHECK_MODULES(MAC_INTEGRATION, ige-mac-integration,, [AC_MSG_ERROR([* ige-mac-integration could not be found. Please install it from https://developer.imendio.com/projects/gtk-macosx/integration])])

  fi

  # Mac OS X doesn't like 'EXPORTS' mentioned in the .def files..strip them out

  grep -v EXPORTS plugins/nntpgrab_plugin.def > tmp

  unlink plugins/nntpgrab_plugin.def

  mv tmp plugins/nntpgrab_plugin.def

  grep -v EXPORTS base/nntpgrab_utils.def > tmp

  unlink base/nntpgrab_utils.def

  mv tmp base/nntpgrab_utils.def

  grep -v EXPORTS nntpgrab_core/nntpgrab.def > tmp

  unlink nntpgrab_core/nntpgrab.def

  mv tmp nntpgrab_core/nntpgrab.def

  grep -v EXPORTS automation/nntpgrab_automation.def > tmp

  unlink automation/nntpgrab_automation.def

  mv tmp automation/nntpgrab_automation.def

  grep -v EXPORTS glue/nntpgrab_glue.def > tmp

  unlink glue/nntpgrab_glue.def

  mv tmp glue/nntpgrab_glue.def

  grep -v EXPORTS gui_base/nntpgrab_gui_base.def > tmp

  unlink gui_base/nntpgrab_gui_base.def

  mv tmp gui_base/nntpgrab_gui_base.def

fi

AC_SUBST(MAC_INTEGRATION_CFLAGS)

AC_SUBST(MAC_INTEGRATION_LIBS)

dnl ---

dnl PCRE is only necessary when GLib 2.14.0 or higher is not found

dnl ---

AC_MSG_CHECKING(if GLIB >= 2.14.0)

pkg-config --atleast-version=2.14.0 glib-2.0

if test `echo $?` = 0; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

  AC_FIND_LIB2(pcre, $ac_default_lib_searchpath, pcre_libraries, [PCRE libraries.], [PCRE libraries could not be found])

  AC_FIND_HEADER2(pcre.h, $ac_default_inc_searchpath, pcre_headers, [PCRE headers.], [PCRE headers could not be found])

fi

if test "$have_soup" = "false" -a "$gui" = "true"; then

  dnl ---------------

  dnl libCURL support

  dnl ---------------

  AC_FIND_LIB2(curl, $ac_default_lib_searchpath, libcurl_libraries,

    [Curl library],

    [Curl library couldn't be found])

  AC_FIND_HEADER2(curl/curl.h, $ac_default_inc_searchpath, libcurl_headers,

    [Curl headers],

    [Curl headers could not be found],

     curl)

fi

AM_CONDITIONAL(HAVE_SSL, $ssl)

if test "$ssl" = "true" ; then

      AC_DEFINE_UNQUOTED(HAVE_SSL, 1, [Do we have to build with SSL support])

      PKG_CHECK_MODULES(GNUTLS,

              gnutls,

              gnutls_found=true; AC_DEFINE_UNQUOTED(HAVE_GNUTLS, 1, [Do we have to build with GNUTLS support]),

              [AC_MSG_RESULT([* GNUTLS could not be found (is the package gnutls-devel installed?)])]; gnutls_found=false)

      if test "$gnutls_found" = "false" ; then

              PKG_CHECK_MODULES(NSS,

                      nss,

                      nss_found=true,

                      [AC_MSG_RESULT([* NSS could not be found (is the package nss-devel installed?)])]; nss_found=false)

              if test "$nss_found" = "true" ; then

                      AC_FIND_LIB(nss_compat_ossl, $ac_default_lib_searchpath, nss_compat_ossl_libraries,

                              [nss_compat_ossl libraries],

                              [nss_compat_ossl libraries could not be found])

                      AC_FIND_HEADER(nss_compat_ossl/nss_compat_ossl.h, $ac_default_inc_searchpath, nss_compat_ossl_headers,

                              [nss_compat_ossl headers],

                              [nss_compat_oss header could not be found],

                              nss_compat_ossl)

              fi

              if test "$nss_found" = "true" -a \

                      "$nss_compat_ossl_libraries_ok" = "true" -a \

                      "$nss_compat_ossl_headers_ok" = "true" ; then

                      have_nss_compat_ossl=true

                      AC_DEFINE_UNQUOTED(HAVE_NSS_COMPAT_OSSL, 1, [Do we have to build with nss-compat-openSSL support])

                      NSS_LIBS="$NSS_LIBS -lnss_compat_ossl"

              else

                      have_nss_compat_ossl=false

                      NSS_CFLAGS=""

                      NSS_LIBS=""

              fi

              if test "$have_nss_compat_ossl" = "false" ; then

                      AC_FIND_LIB2(ssl, $ac_default_lib_searchpath, openssl_libraries,

                              [OpenSSL libraries],

                              [OpenSSL library not found])

                      AC_FIND_HEADER2(openssl/md5.h, $ac_default_inc_searchpath, openssl_headers,

                              [OpenSSL headers],

                              [OpenSSL headers could not be found])

                      openssl_libraries_LIBS="$openssl_libraries_LIBS -lcrypto"

              fi

      fi

fi

AC_SUBST(PCRE_CFLAGS, $pcre_headers_CFLAGS)

AC_SUBST(PCRE_LIBS, $pcre_libraries_LIBS)

AC_SUBST(CURL_CFLAGS, $libcurl_headers_CFLAGS)

AC_SUBST(CURL_LIBS, $libcurl_libraries_LIBS)

AC_SUBST(GNUTLS_CFLAGS)

AC_SUBST(GNUTLS_LIBS)

AC_SUBST(NSS_CFLAGS)

AC_SUBST(NSS_LIBS)

AC_SUBST(OPENSSL_CFLAGS, $openssl_headers_CFLAGS)

AC_SUBST(OPENSSL_LIBS, $openssl_libraries_LIBS)

# Introspection support

GOBJECT_INTROSPECTION_CHECK([0.9.0])

# gettext

AC_PROG_INTLTOOL([0.21], [no-xml])

AC_PATH_PROG(MSGFMT, msgfmt, msgfmt)

ALL_LINGUAS="nl fr"

AM_GLIB_GNU_GETTEXT

if test "x$WIN32_TRUE" = "x" ; then

    nntpgrablocaledir='../${DATADIRNAME}/locale'

else

    nntpgrablocaledir='${prefix}/${DATADIRNAME}/locale'

fi

AC_SUBST(nntpgrablocaledir)

AC_CHECK_FUNC(strptime,[ AC_DEFINE(HAVE_STRPTIME, 1, [strptime check]) AM_CONDITIONAL(HAVE_STRPTIME, true) ],[ AM_CONDITIONAL(HAVE_STRPTIME, false) ])

AC_CHECK_FUNC(backtrace_symbols, [AC_DEFINE(HAVE_BACKTRACE, 1, [backtrace_symbols check])])

dnl Checks for mkdtemp function

mkdtemp_missing=false

AC_CHECK_FUNC(mkdtemp,

    [AC_DEFINE([HAVE_MKDTEMP], 1, [Have GlibC function to make temp dirs])],

    mkdtemp_missing=true)

AM_CONDITIONAL(MKDTEMP_MISSING, test x$mkdtemp_missing = xtrue)

dnl Set PACKAGE SOURCE DIR in config.h.

packagesrcdir=`cd $srcdir && pwd`

dnl Set PACKAGE PREFIX

if test "x${prefix}" = "xNONE"; then

  packageprefix=${ac_default_prefix}

else

  packageprefix=${prefix}

fi

packagedatadir=share/${PACKAGE}

pkgdir=${packageprefix}/${packagedatadir}

plugindir=${libdir}/${PACKAGE}

wwwdir=${pkgdir}/web

AC_DEFINE_UNQUOTED(SHARE_DIR, "${pkgdir}", [Location of NNTPGrab icons])

AC_SUBST(PLUGINDIR, "${plugindir}")

AC_SUBST(WWWDIR, "${wwwdir}")

CPPFLAGS="$CPPFLAGS -DPLUGIN_DIR=\"\\\"\${PLUGINDIR}\\\"\" -DWWW_DIR=\"\\\"\${WWWDIR}\\\"\""

# -fstack-protector

AC_ARG_ENABLE([stack-protector],

    [AS_HELP_STRING([--disable-stack-protector],

        [Disable GCC's/libc's stack-smashing protection])],

    [case "${enableval}" in

         yes) enable_ssp=yes ;;

          no) enable_ssp=no ;;

           *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;

     esac],

    [enable_ssp=yes])

if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then

    AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])

    enable_ssp=no

fi

if test x"$enable_ssp" = x"yes"; then

    # Check for broken ssp in libc: https://www.avahi.org/ticket/105

    # libc's brokenness will get in the way regardless of whether -lssp is

    # provided, but provide it anyway (otherwise non-libc ssp would wrongly

    # break here)

    # Get -lssp if it exists

    GCC_STACK_PROTECT_LIB

    AC_MSG_CHECKING([whether stack-smashing protection is available])

    ssp_old_cflags="$CFLAGS"

    ssp_old_ldflags="$LDFLAGS"

    CFLAGS="$CFLAGS -fstack-protector-all -fPIC"

    LDFLAGS="$LDFLAGS -Wl,-z,defs"

    cat confdefs.h > conftest.c

    cat >>conftest.c <<_ACEOF

void test_broken_ssp(c)

    const char *c;

{

    char arr[[123]], *p; /* beware of possible double-braces if copying this */

    for (p = arr; *c; ++p) {

        *p = *c;

        ++c;

    }

}

_ACEOF

    rm -f conftest.o

    if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then

        AC_MSG_RESULT([yes])

        AC_MSG_CHECKING([whether stack-smashing protection is buggy])

        if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then

            AC_MSG_RESULT([no])

        else

            AC_MSG_RESULT([yes])

            enable_ssp=no

        fi

    else

        AC_MSG_RESULT([no])

    fi

    rm -f conftest.c conftest.o conftest.so

    CFLAGS="$ssp_old_cflags"

    LDFLAGS="$ssp_old_ldflags"

fi

if test x"$enable_ssp" = x"yes"; then

    # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice

    GCC_STACK_PROTECT_CC

    AC_LANG_PUSH([C++])

    GCC_STACK_PROTECT_CXX

    AC_LANG_POP([C++])

    # XXX: Update the enable_ssp value now for output later?

fi

if test "$php_module" = "true" ; then

    AC_CONFIG_SUBDIRS(client/web/module)

fi

AC_OUTPUT([

Makefile

docs/Makefile

docs/reference/Makefile

docs/reference/version.xml

po/Makefile.in

base/Makefile

base/nntpgrab_utils.pc

gui_base/Makefile

automation/Makefile

automation/nntpgrab_automation.pc

nntpgrab_core/Makefile

nntpgrab_core/nntpgrab.pc

glue/Makefile

glue/nntpgrab_glue.pc

server/Makefile

plugins/Makefile

plugins/antisleep/Makefile

plugins/auto_import/Makefile

plugins/decoder/Makefile

plugins/example/Makefile

plugins/jsonrpc/Makefile

plugins/logger/Makefile

plugins/networkmanager/Makefile

plugins/par2/Makefile

plugins/unpack/Makefile

client/Makefile

client/web/Makefile

client/gui/Makefile

tests/Makefile

])