NNTPGrab

; nntpgrab.nsi

;

;!include "MUI.nsh"

;!include "Sections.nsh"

!include "registerExtension.nsh"

;--------------------------------

; The name of the installer

Name "NNTPGrab"

; The file to write

OutFile "nntpgrab_trunk_snapshot_svn_r@VER@_setup.exe"

; The default installation directory

InstallDir $PROGRAMFILES\NNTPGrab

; Registry key to check for directory (so if you install again, it will 

; overwrite the old one automatically)

InstallDirRegKey HKLM "Software\NNTPGrab" "Install_Dir"

; Best compression

SetCompressor lzma

;--------------------------------

; Check if the program is running

!define WNDCLASS "gdkWindowTopLevel"

!define WNDTITLE "NNTPGrab"

Function .onInit

  FindWindow $0 "${WNDCLASS}" "${WNDTITLE}"

  StrCmp $0 0 continueInstall

    MessageBox MB_ICONSTOP|MB_OK "The installation cannot continue because NNTPGrab is still running. Please close NNTPGrab and try again."

    Abort

  continueInstall:

FunctionEnd

;--------------------------------

; Pages

LicenseData "COPYING"

Page license

Page components

Page directory

Page instfiles

UninstPage uninstConfirm

UninstPage instfiles

;--------------------------------

; The stuff to install

Section "NNTPGrab (required)"

  SectionIn RO

  SetOutPath $INSTDIR\bin

  File "dist\bin\exchndl.dll"

  File "dist\bin\gspawn-win32-helper.exe"

  File "dist\bin\gspawn-win32-helper-console.exe"

  File "dist\bin\libffi-6.dll"

  File "dist\bin\libgcc_s_sjlj-1.dll"

  File "dist\bin\libgio-2.0-0.dll"

  File "dist\bin\libglib-2.0-0.dll"

  File "dist\bin\libgmodule-2.0-0.dll"

  File "dist\bin\libgobject-2.0-0.dll"

  File "dist\bin\libgthread-2.0-0.dll"

  File "dist\bin\iconv.dll"

  File "dist\bin\libintl-8.dll"

  File "dist\bin\libnntpgrab_automation-0.dll"

  File "dist\bin\libnntpgrab_utils-0.dll"

  File "dist\bin\libnntpgrab_glue-0.dll"

  File "dist\bin\libnntpgrab-0.dll"

  File "dist\bin\libpng15-15.dll"

  File "dist\bin\libproxy.dll"

  File "dist\bin\QtCore4.dll"

  File "dist\bin\QtNetwork4.dll"

  File "dist\bin\QtGui4.dll"

  File "dist\bin\libsoup-2.4-1.dll"

  File "dist\bin\libsoup-gnome-2.4-1.dll"

  File "dist\bin\libsqlite3-0.dll"

  File "dist\bin\libtasn1-3.dll"

  File "dist\bin\libxml2-2.dll"

  File "dist\bin\libstdc++-6.dll"

  File "dist\bin\nntpgrab_gui.exe"

  File "dist\bin\nntpgrab_gui_debug.exe"

  File "dist\bin\nntpgrab_server.exe"

  File "dist\bin\nntpgrab_server_qt.exe"

  File "dist\bin\par2.exe"

  File "dist\bin\UnRAR.exe"

  File "dist\bin\zlib1.dll"

  File "client\gui\nntpgrab.ico"

  # Start GnuTLS libraries

  File "dist\bin\libgpg-error-0.dll"

  File "dist\bin\libgcrypt-11.dll"

  File "dist\bin\libp11-kit-0.dll"

  File "dist\bin\libgnutls-26.dll"

  # Start GIO TLS module

  SetOutPath $INSTDIR\lib\gio\modules

  File "dist\lib\gio\modules\giomodule.cache"

  File "dist\lib\gio\modules\libgiognutls.dll"

  SetOutPath $INSTDIR\lib\nntpgrab

  File "dist\lib\nntpgrab\*.dll"

  SetOutPath $INSTDIR\share\nntpgrab\translations

  File "dist\share\nntpgrab\translations\*.qm"

  SetOutPath $INSTDIR\share\locale\nl\LC_MESSAGES

  File "dist\share\locale\nl\LC_MESSAGES\*.mo"

  ; Write the installation path into the registry

  WriteRegStr HKLM SOFTWARE\NNTPGrab "Install_Dir" "$INSTDIR"

  ; Write the uninstall keys for Windows

  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\NNTPGrab" "DisplayName" "NNTPGrab"

  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\NNTPGrab" "UninstallString" '"$INSTDIR\uninstall.exe"'

  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\NNTPGrab" "NoModify" 1

  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\NNTPGrab" "NoRepair" 1

  WriteUninstaller "uninstall.exe"

  SetOutPath $INSTDIR\bin

  CreateDirectory "$SMPROGRAMS\NNTPGrab"

;  CreateShortCut "$SMPROGRAMS\NNTPGrab\License.lnk" "$INSTDIR\COPYING.txt" "" "$INSTDIR\COPYING.txt" 0

  CreateShortCut "$SMPROGRAMS\NNTPGrab\Uninstall.lnk" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0

  CreateShortCut "$SMPROGRAMS\NNTPGrab\NNTPGrab.lnk" "$INSTDIR\bin\nntpgrab_gui.exe" "" "$INSTDIR\bin\nntpgrab.ico" 0

  CreateShortCut "$SMPROGRAMS\NNTPGrab\NNTPGrab Server.lnk" "$INSTDIR\bin\nntpgrab_server_qt.exe" "" "$INSTDIR\bin\nntpgrab.ico" 0

SectionEnd

Section ".NZB File association"

  ${registerExtension} "$INSTDIR\bin\nntpgrab_gui.exe" ".nzb" "NNTPGrab"

SectionEnd

Section "Webinterface"

  SetOutPath $INSTDIR\webinterface

  File "plugins\jsonrpc\web\*.html"

  SetOutPath $INSTDIR\webinterface\css

  File "plugins\jsonrpc\web\css\*.css"

  SetOutPath $INSTDIR\webinterface\css\images

  File "plugins\jsonrpc\web\css\images\*.png"

  SetOutPath $INSTDIR\webinterface\javascript

  File "plugins\jsonrpc\web\javascript\*.js"

SectionEnd

;--------------------------------

; Uninstaller

Section "Uninstall"

  ; Remove registry keys

  DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\NNTPGrab"

  DeleteRegKey HKLM SOFTWARE\NNTPGrab

  ; Remove files and uninstaller

  Delete $INSTDIR\webinterface\javascript\*.*

  RMDir  $INSTDIR\webinterface\javascript

  Delete $INSTDIR\webinterface\css\images\*.*

  RMDir  $INSTDIR\webinterface\css\images

  Delete $INSTDIR\webinterface\css\*.*

  RMDir  $INSTDIR\webinterface\css

  Delete $INSTDIR\webinterface\*.*

  RMDir  $INSTDIR\webinterface

  Delete $INSTDIR\share\locale\nl\LC_MESSAGES\*.*

  RMDir  $INSTDIR\share\locale\nl\LC_MESSAGES

  Delete $INSTDIR\share\locale\nl\*.*

  RMDir  $INSTDIR\share\locale\nl

  Delete $INSTDIR\share\locale\*.*

  RMDir  $INSTDIR\share\locale

  Delete $INSTDIR\share\nntpgrab\translations\*.*

  RMDir  $INSTDIR\share\nntpgrab\translations

  Delete $INSTDIR\share\nntpgrab\*.*

  RMDir  $INSTDIR\share\nntpgrab

  RMDir  $INSTDIR\share

  Delete $INSTDIR\lib\nntpgrab\*.*

  RMDir  $INSTDIR\lib\nntpgrab

  Delete $INSTDIR\lib\gio\modules\*.*

  RMDir  $INSTDIR\lib\gio\modules

  RMDir  $INSTDIR\lib\gio

  Delete $INSTDIR\lib\*.*

  RMDir  $INSTDIR\lib

  Delete $INSTDIR\bin\*.*

  RMDir  $INSTDIR\bin

  Delete $INSTDIR\*.*

  RMDir  $INSTDIR

  ; Remove shortcuts, if any

  Delete "$SMPROGRAMS\NNTPGrab\*.*"

  ; Remove directories used

  RMDir "$SMPROGRAMS\NNTPGrab"

  RMDir "$INSTDIR"

  ; Delete file associations

  ${unregisterExtension} ".nzb" "NZB File"

SectionEnd